Doens.be » DictTable

Loop all tables

Jeroen Doens — Thu, 16 Sep 2010 05:00:18 +0000

There is a simple trick to loop all tables that are available in Ax. Just use the Dictionary-class that contains all information about tables.

Small example to list all tablenames + their corresponding Id.

static void JeDoe_listTables(Args _args)
{
    Dictionary  dictionary = new Dictionary();
    int         i;
    ;
    for (i=1 ; i<=dictionary.tableCnt() ; i++)
    {
        info(strfmt('%1;%2', dictionary.tableCnt2Id(i), tableid2name( dictionary.tableCnt2Id(i) )));
    }
}

When you combine this with a DictTable / DictField-object, there are lots of possibilities.

A few things you should know about temporary tables

Jeroen Doens — Mon, 10 May 2010 05:00:43 +0000

How do you set a table temporary:

You can set the property ‘temporary’ in the AOT to yes –> this table is always temporary
You can declare a buffer of a table and call the method setTemp() or setTempData(), from that moment on the buffer contains temporary data.
```
CustTable custTable;
;
custTable.setTmp();
if (custTable.isTmp())
{
    // Do something with your temporary table
}
```

Things to know:

When you declare a buffer of a record of temporary table type, the table does not contain any values.
Memmory and filespace aren’t allocated for a temporary table till the first record is inserted. This means that you have to watch out for client/server problems.
When the first record is inserted in a buffer on the client tier, the memory is allocated there. All actions (insert / update / delete) to this buffer will run trough that tier, so try to reduce round-trips and improve your performance.
When you declare 2 different buffers of the same temporary table, they will both have a life of their own. To share the date between the tables use the setTmpData method.
for example: tmpCommonBuffer1.setTmpData(tmpCommonBuffer2);
You can’t (normally) set up logging on temporary tables.
Use the method isTmp() to know if a record is temporary or not (true –> temporary, false –> phisical)

My opinion: Temporary tables are very useful and can help you to easily manipulate data you don’t need store permanently, but watch out where and how you use them.

List of mandatory fields on a table

Jeroen Doens — Mon, 22 Feb 2010 07:00:28 +0000

When you want a list of all the mandatory field on table X, yould check all the properties on the table fields, or you could be lazy and write a small job that does the trick for you. Just replace TableId with your tablenum.

static void CheckMandatoryFieldsOnTable(Args _args)
{
    DictTable dictTable;
    DictField dictField;
    int i;
    TableId tableId = tablenum(custtable);
    ;
    dictTable = new DictTable(tableId);
    for (i=1 ; i<=dictTable.fieldCnt() ; i++)
    {
        dictField = new DictField(tableId, dictTable.fieldCnt2Id(i));
        if (dictField.mandatory())
        {
            info(dictField.name());
        }
    }
}

Moving DB-objects to other layers … without losing data

Jeroen Doens — Sun, 14 Feb 2010 07:00:15 +0000

Most of us have already been confronted with the problem of tables being inserted in the wrong layer, and when they already contain data it is very difficult to transfer these objects to the correct layer without losing data.

I found the following article on Axaptapedia that helps you with this issue: http://www.axaptapedia.com/Move_DB_objects_to_another_layer

Select a record from a table when you only have the tableId

Jeroen Doens — Thu, 16 Jul 2009 15:34:57 +0000

The following code can provide you a generic way to update a table when you only have the tableId.

public Common findRecord(TableId _tableId, RecId _recId, Boolean _forUpdate = false)
{
    Common      common;
    DictTable   dictTable;
    ;
    dictTable = new DictTable(_tableId);
    common = dictTable.makeRecord();
 
    common.selectForUpdate(_forUpdate);
 
    select common
    where common.RecId == _recId;
 
    return common;
}

If you want, you can even update fields in this common record. You can Access/edit these fields by using their Name or FieldNum. The method below will update a specific field in a table.

public void updateValue(TableId _tableId, RecId _recId, str _field, AnyType _value)
{
    Common      common;
    Int         fieldId;
    ;
    ttsbegin;
    common = findRecord(_tableId, _recId, true);
    fieldId = fieldname2id(_tableId,_field);
 
    if (fieldId &amp;&amp; _value)
    {
        common.(fieldId) = _value;
        common.update();
    }
    ttscommit;
}